Esp Wroom 32

Home > ESP

Driver Setup :

https://www.silabs.com/developers/usb-to-uart-bridge-vcp-drivers?tab=downloads

Enter the following into the “Additional Board Manager URLs” field :

 https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json

LED BLINK :

void setup() {
    // initialize digital pin LED_BUILTIN as an output
    pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
    // the loop function runs over and over again forever
    digitalWrite(LED_BUILTIN, HIGH);  // turn the LED on (HIGH is the voltage level)
    delay(1000);                      // wait for a second
    digitalWrite(LED_BUILTIN, LOW);   // turn the LED off by making the voltage LOW
    delay(1000);                      // wait for a second
}

EXTERNAL LED BLINK :

 /***
* LED Blinking
* Code Written by TechMartian
*/
const int ledPin = 5;
   
void setup() {
    // setup pin 5 as a digital output pin
    pinMode(ledPin, OUTPUT);
}
   
void loop() {
       digitalWrite(ledPin, HIGH);  // turn on the LED
       delay(500);                  // wait for half a second or 500 milliseconds
       digitalWrite(ledPin, LOW);   // turn off the LED
       delay(500);                  // wait for half a second or 500 milliseconds
   }

OLED :

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define OLED_ADDR 0x3C
Adafruit_SSD1306 display(128, 64, &Wire, -1);

void setup() {
    display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR);
    display.clearDisplay();
    display.setTextColor(WHITE);
    display.setTextSize(2);
    display.setCursor(10, 20);
    display.println("Embed Club");
    display.display();
}

void loop() {}

ULTRA SONIC SENSOR :

const int trigPin = 5;
const int echoPin = 18;
// Define sound speed in cm/uS
const float SOUND_SPEED = 0.034;
            
long duration;
float distanceCm;
            
void setup() {
    Serial.begin(9600); // Start serial communication
    pinMode(trigPin, OUTPUT); // Set trigPin as an output
    pinMode(echoPin, INPUT); // Set echoPin as an input
}
            
void loop() {
    // Clear trigPin
    digitalWrite(trigPin, LOW);
    delayMicroseconds(2);
                
    // Set trigPin to HIGH state for 10 microseconds
    digitalWrite(trigPin, HIGH);
    delayMicroseconds(10);
    digitalWrite(trigPin, LOW);
                
    // Read echoPin, return sound wave travel time in microseconds
    duration = pulseIn(echoPin, HIGH);
                
    // Calculate distance
    distanceCm = (duration * SOUND_SPEED) / 2;
                
    // Print distance to Serial Monitor
    Serial.print("Distance (cm): ");
    Serial.println(distanceCm);
                
    delay(1000); // Wait for a second
}

ULTRA SONIC SENSOR & OLED DISPLAY :

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define OLED_ADDR 0x3C
Adafruit_SSD1306 display(128, 64, &Wire, -1);

const int trigPin = 5;
const int echoPin = 18;
// Define sound speed in cm/uS
const float SOUND_SPEED = 0.034;

long duration;
float distanceCm;

void setup() {
    // Initialize serial communication
    Serial.begin(9600);

    // Initialize the OLED display
    display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR);
    display.clearDisplay();
    display.setTextColor(WHITE);
    display.setTextSize(2);

    // Initialize ultrasonic sensor pins
    pinMode(trigPin, OUTPUT);
    pinMode(echoPin, INPUT);
}

void loop() {
    // Clear trigPin
    digitalWrite(trigPin, LOW);
    delayMicroseconds(2);
    
    // Set trigPin to HIGH state for 10 microseconds
    digitalWrite(trigPin, HIGH);
    delayMicroseconds(10);
    digitalWrite(trigPin, LOW);
    
    // Read echoPin, return sound wave travel time in microseconds
    duration = pulseIn(echoPin, HIGH);
    
    // Calculate distance
    distanceCm = (duration * SOUND_SPEED) / 2;
    
    // Print distance to Serial Monitor
    Serial.print("Distance (cm): ");
    Serial.println(distanceCm);
    
    // Display distance on OLED
    display.clearDisplay();
    display.setCursor(0, 20);
    display.print("Distance: ");
    display.print(distanceCm);
    display.print(" cm");
    display.display();
    delay(1000); // Wait for a second
}

IOT WITH MOBILE APPLICATION :

#include <WiFi.h>
const char WiFiPassword[] = "1234567890";
const char AP_NameChar[] = "embedclub" ;
WiFiServer server(80);
String header = "HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n\r\n";
String html_1 = "<!DOCTYPE html><html><head><title>LED Control</title></head><body><div id='main'><h2>LED Control</h2>";
String html_2 = "<form id='F1' action='LEDON'><input class='button' type='submit' value='LED ON' ></form><br>";
String html_3 = "<form id='F2' action='LEDOFF'><input class='button' type='submit' value='LED OFF' ></form><br>";
String html_4 = "</div></body></html>";
 String request = "";
int LED_Pin = 2; // Use GPIO2 for the LED on ESP32
void setup() {
                pinMode(LED_Pin, OUTPUT); 
                digitalWrite(LED_Pin, HIGH); // Turn off LED initially (assuming active low)
                boolean conn = WiFi.softAP(AP_NameChar, WiFiPassword);
                server.begin();
}
void loop() {
    // Check if a client has connected
    WiFiClient client = server.available();
    if (!client)  {  return;  }

    // Read the first line of the request
    request = client.readStringUntil('\r');

    if (request.indexOf("LEDON") > 0)  { 
        digitalWrite(LED_Pin, LOW);  // Turn the LED on (assuming active low)
    } 
    else if (request.indexOf("LEDOFF") > 0) { 
        digitalWrite(LED_Pin, HIGH);  // Turn the LED off
    }
    client.flush();
    client.print(header);
    client.print(html_1);
    client.print(html_2);
    client.print(html_3);
    client.print(html_4);
    delay(5);
    // The client will actually be disconnected when the function returns and 'client' object is destroyed
}

HOME AUTOMATION :

/*
 * Simple example for how to use multiple SinricPro Switch device:
 * - setup 4 switch devices
 * - handle request using multiple callbacks
 * 
 * If you encounter any issues:
 * - check the readme.md at https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/README.md
 * - ensure all dependent libraries are installed
 *   - see https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/README.md#arduinoide
 *   - see https://github.com/sinricpro/esp8266-esp32-sdk/blob/master/README.md#dependencies
 * - open serial monitor and check whats happening
 * - check full user documentation at https://sinricpro.github.io/esp8266-esp32-sdk
 * - visit https://github.com/sinricpro/esp8266-esp32-sdk/issues and check for existing issues or open a new one
 */


 #ifdef ENABLE_DEBUG
 #define DEBUG_ESP_PORT Serial
 #define NODEBUG_WEBSOCKETS
 #define NDEBUG
#endif 

#include <Arduino.h>
#if defined(ESP8266)
#include <ESP8266WiFi.h>
#elif defined(ESP32) || defined(ARDUINO_ARCH_RP2040)
#include <WiFi.h>
#endif

#include "SinricPro.h"
#include "SinricProSwitch.h"

#define WIFI_SSID         "Thameem"
#define WIFI_PASS         "11111111"
#define APP_KEY           "40da6700-a055-454c-83ac-a8dff244813c"
#define APP_SECRET        "5a5671f1-7259-4b34-98a7-ef7d5af05b18-4fb59651-534f-4bd0-9d6d-f54fe0bf1e35"

#define SWITCH_ID_1       "6496a856743f9120703ed6c6"
#define RELAYPIN_1        25

#define BAUD_RATE         115200                // Change baudrate to your need

bool onPowerState1(const String &deviceId, bool &state) {
  bool invertedState = !state;
  Serial.printf("Device 1 turned %s", invertedState ? "on" : "off");
  digitalWrite(RELAYPIN_1, invertedState ? HIGH : LOW);
  return true; // request handled properly
}

// setup function for WiFi connection
void setupWiFi() {
  Serial.printf("\r\n[Wifi]: Connecting");

  #if defined(ESP8266)
    WiFi.setSleepMode(WIFI_NONE_SLEEP); 
    WiFi.setAutoReconnect(true);
  #elif defined(ESP32)
    WiFi.setSleep(false); 
    WiFi.setAutoReconnect(true);
  #endif

  WiFi.begin(WIFI_SSID, WIFI_PASS);

  while (WiFi.status() != WL_CONNECTED) {
    Serial.printf(".");
    delay(250);
  }

  Serial.printf("connected!\r\n[WiFi]: IP-Address is %s\r\n", WiFi.localIP().toString().c_str());
}

// setup function for SinricPro
void setupSinricPro() {
  // add devices and callbacks to SinricPro
  pinMode(RELAYPIN_1, OUTPUT);
    
  SinricProSwitch& mySwitch1 = SinricPro[SWITCH_ID_1];
  mySwitch1.onPowerState(onPowerState1);
  
  
  // setup SinricPro
  SinricPro.onConnected([](){ Serial.printf("Connected to SinricPro\r\n"); }); 
  SinricPro.onDisconnected([](){ Serial.printf("Disconnected from SinricPro\r\n"); });
   
  SinricPro.begin(APP_KEY, APP_SECRET);
}

// main setup function
void setup() {
  Serial.begin(BAUD_RATE); Serial.printf("\r\n\r\n");
  setupWiFi();
  setupSinricPro();
}

void loop() {
  SinricPro.handle();
}